Code

////////////////////////////////////////////////////////////////////////////////////
// Calculate Interest paid on an account
//
// Layout Elements used:
// Acct#  - account number
// PayID    - Unique payment Identifier
// PmtDate  - Date of payment
// PmtHere  - Amount Paid to Us
// PmtDir   - Amount Paid to Client
// List Amt - Amount account was listed for
// Int_Pd   - Amount of interest paid on the account
////////////////////////////////////////////////////////////////////////////////////

var vPIDs as string            // Variable to store payments on account
var vNextOne as string            // Variable to act as temporary active payment acct
var vPaymentInfo as string      // Variable to store retrieve information
var vTotalOfPay as double      // variable to store total of payments

// variables to be converted from vPaymentInfo - to ease processing.
var vCurDate as date
var vCurPmtH as double
var vCurPmtD as double

vTotalOfPay = 0;

if @IsBlank(PmtHere) then
{
}
else
{
      // Perform a lookup on the current database for the current account
      // and pull up all Payment ID's to identify each payment. And store it in vPIDs
      vPIDs = @XLookupAll(@fn,Acct#,"Acct#","PayID")
      // store in VPIDs semicolon delimited list of Payment ID's where the
      // current Acct# matches the Acct# in the current database.

      // while there are still payments unaccounted for.
      while @Len(vPIDs) > 0
      {
            // Set vNextOne to the next payment in the list.
            vNextOne = Split(vPids,";");

            // Pull up the payment where current payment (vNextOne) matches.
            // The unique paymentID in the database.
            // Retrieve PmtDate, PmtHere and PmtDir fields and separate them by semicolons.
            vPaymentInfo = @XLookupSourceList(@Fn, vNextOne, "PaymentID", "PmtDate;PmtHere;PmtDir");
            
            // Process the payment
            vCurDate = @ToDate (Split(vPaymentInfo,";"));
            vCurPmtH = @ToMoney(Split(vPaymentInfo,";"));
            vCurPmtD = @ToMoney(Split(vPaymentInfo,";"));

            // if the payment is not after today and it is not this payment
            if (vCurDate <= @Date AND vNextOne <> PayID) then
            {
                  // add current payment here & dir to the total
                  // one should always be 0 while the other should have an amount.
                  vTotalOfPay += vCurPmtH;
                  vTotalOfPay += vCurPmtD;
            }

      } // END WHILE
}

// if there was interest paid (more was paid than listed amt)
if vTotalOfPay > List Amt then
{
      // set Int_Pd to the amount of the interest that has been paid.
      Int_Pd = vTotalOfPay - List Amt;
}
else // otherwise
{
      // set Int_Pd to 0
      Int_Pd = 0;
}