For some reason, I cant get Sesame to open a .txt file. I've tried several different programs, and none of them will read the contents of the file. The file is a plain text file (copied from website and pasted into excel, then saved as .TXT). It opens fine in notepad:

var vall as string = ""
vall = @insert("c:\temp\colors5.txt")
writeln("vall = " + vall)

The writeln window is blank. also:

var vfilehandle as int
var vfilesize as int
var vfile as string
var vline as string = ""

if fileExists("C:\temp\colors5.txt") then writeln("Found it") else writeln("Cant find it!")

vfilehandle = fileopen("c:\temp\colors5.txt")
vfilesize= filesize(vfilehandle)
filereadln(vfilehandle, vline)
writeln(vline)

Here the writeln window shows "Found it"  and nothing else.

I restarted client, and put the text file in the c:\temp folder on BOTH client and server, but still no luck.

Any ideas? I've never had this problem before.

Steve

Yes, other text files are being opened just fine. Also, I've used this routine before and occasionally run into a problem where sesame doesnt find certain character such as @newline().

But it seems this time, sesame cant read any of it at all. Using @Asc(vline) just returns 0.

Can you think of a way to get the data in excel into a more Sesame friendly format? Pasting from Excel into notepad doesn't help and I dont see an 'export' tool in excel.

Thanks,
Steve

I always save as .csv from excel which usually works fine.

I'll send you the text file. Thanks for the help.

Steve

Bob,

I copied a table (chart?) and which pasted nicely into excel. Then I used Excels features and speed to do a lot of search/replacing. Keeping things in neat rows and columns is essential.

Then I saved to a .csv and usually import it right into sesame using Sbasic programming.

Maybe I should look at search/replace program other than excel. (Notepad is SOO SLOOOWW, but necessary to 'clean up' the .csv before importing into Sesame)

Thanks,
Steve

Thanks Serge. I have found Word pad to be much faster, but I was worred that wordpad my add change my "generic text" to "Rich Text" and further complicate things during my import into sesame. Also, the 'wordwrap' throws my lines out of whack. I like to see the data as 'raw' as possible.

Thanks for all the suggestions. Keep em coming.

Steve

Steve,

I now have your file, and I am seeing a few problems, some with the SBasic (as posted) and a minor problem with the file.

The following SBasic will not work because of the length of the file: 

var vall as string = ""
vall = @insert("c:\temp\colors5.txt")
writeln("vall = " + vall)
 

The file is 382K as received. The writeln window will vertically wrap every 32K (clear, and start at the top again) and dumping 382K on a single line is just too much for it to manage. You will need to break your string into smaller pieces if you need to send them to the writeln window, so each line of text is smaller.

The good news is that the variable "vall" is getting set to the entire string - even if that cannot be shown using a single writeln call.

The other attempt to read the file is suffering because, FileOpen expects to be used read/write - so if the file already exists it positions the "file pointer" (the position where the next operation will occur in the file) to the end of the file - to make appending to an existing file very easy. Before reading from an existing file, you should always do a "FileSeek" operation. The following will read the first line in your file:

vfilehandle = fileopen("c:\temp\colors5.txt")
fileseek(vfilehandle, 0)
filereadln(vfilehandle, vline)
writeln(vline)
fileclose(vfilehandle)
 

The last problem I am seeing, is that the file is not "DOS" formatted. All operating systems other than those from Microsoft (Unixes, VMS, Mac, etc..) end each line with a single line feed. Microsoft OSs (on the other hand) end each line with a linefeed / carriage return pair. The file you sent only has the single linefeed. So, it appears that it originated on an operating system other than a Microsoft OS. This is not a bad problem because Sesame and most other programs are built to accomodate either line ending.

Quote:


The file does have linefeeds. It seems to missing carriage returns. That should be okay and you probably won't need to do anything about that.

I would recommend that you get rid of the @Insert and its accompanying WriteLn, and use the file I/O to read the file in one line at a time. That way, you do not have to parse it into separate lines at all. Once you have read a line you can parse it, or concatenate it, or merely send it to the "slate" with WriteLn - as is needed.

Anything you pass to WriteLn, WriteLn will treat as one big "chunk" even if it has linefeed embedded in it. It measures the string length - not the line length. A string can have many lines in it, each demarcated with either a single linefeed or a lf/cr pair.

You're welcome.

Steve,

Some preliminary results from testing your code:
Quote:

No, 4500 lines is easily handled. That error (in this case) is coming from the "+=" operator. When I replaced:

t[x,1] = split(vline, ",") + ","
t[x,1] += split(vline, ",") + ","
t[x,1] += split(vline, ",") + ","
 

With:

t[x,1] = split(vline, ",") + ","
t[x,1] = t[x,1] + split(vline, ",") + ","
t[x,1] = t[x,1] + split(vline, ",") + ","
 

The error goes away. The two constructs are supposed to be identical. The "+=" operator is borrowed from a different language (the computer language called "C") the second construct is the typical way to concatenate in BASIC. I am now looking into the "+=" operator to see why it is acting differently. It is either having a problem with strings, or with arrays - you have both, so I am not sure which is giving it grief.

In the category of good advice, before you deploy this code, please make sure that you are checking if the file exists before you attempt to open it and that you have successfully opened it before you attempt to check file size or read. The check you do have, informs the user, but provides no means to prevent the subsequent operations.

var vfilehandle as int
var vfilesize as int
var vline as string = ""
var x as int = 1
var vrecord as string = ""
VAR t as array [5000,4] of string
var z as int
var nn as int
var vall as string
var vresults as int
var vfile as string

if fileExists("C:\temp\color7.txt")
{
 writeln("Found it")

 vfilehandle = fileopen("c:\temp\color7.txt")
 if(vfilehandle > 0)
 {
  vfilesize = filesize(vfilehandle)
  fileseek(vfilehandle, 0)

  while(filepos(vfilehandle) < vfilesize)
  {
   filereadln(Vfilehandle, vline)
   t[x,1] = split(vline, ",") + ","
   t[x,1] = t[x,1] + split(vline, ",") + ","
   t[x,1] = t[x,1] + split(vline, ",") + ","
   t[x,2] = split(vline, ",") //all with no spaces
   t[x,3] = split(vline, ",") //size
   t[x,4] = split(vline, @newline())   //stock number
   x = x + 1
  }
  fileclose(vfilehandle)
 }
}
else
{
 writeln("Cant find it!")
}

 

Thanks for the info.

I'll give it a try.

Steve

Mark,

I want to put this program into a mass update but the T array needs to be available to every record in the mass update.

The program works with the first record, but then the array is killed when the record changes to the next one.

I put ' Var T as array(5000, 5) as string' in the Global Code section so it would not be killed between records, but now I'm freezing up.

Here's the program that is in a 'general area' of Mass Update:

var vfilehandle as int
var vfilesize as int
var vline as string = ""
var x as int =1
var vrecord as string = ""
var nn as int
var vall as string
var vresults as int
var vfile as string

if @formresultsetcurrentposition("admin") = 1 then
{
if fileExists("C:\temp\shawimport.txt") then writeln("Found it")

vfilehandle = fileopen("c:\temp\shawimport.txt")
vfilesize= filesize(vfilehandle)
fileseek(vfilehandle, 0)

while (filepos(vfilehandle)) < (vfilesize)
{
filereadln(Vfilehandle, vline)
t[x,1] = split(vline, ",") + ","
t[x,1] = t[x,1] + split(vline, ",") + ","
t[x,1] = t[x,1] + split(vline, ",") + ","
t[x,2] = split(vline, ",") //all with no spaces
t[x,3] = split(vline, ",") //size
t[x,4] = vline   //stock number
x=x+1
}
z=x-1
fileclose(vfilehandle)
}//end of file open

vrecord = COLLECTION + pattern + color
vrecord = @replace(vrecord, " ", "")
vrecord = @replace(vrecord, "-", "")
vrecord = @replace(vrecord, "'", "")
writeln("Vrecord = " + vrecord)

x=1
writeln("about to scroll through lines since x = " + x + " and z = "+z)

while x <= z
{
//writeln("Comparing :" + t[x,1] + " against " + vrecord)

if t[x,2] = vrecord then
{
nn=@formnewrecord("Variants")
formfieldvalue("Variants", "mfgr", nn, "Shaw2")
formfieldvalue("variants", "variant Name", nn, t[x,3])
formfieldvalue("Variants", "part number", nn, t[x,4])
writeln("Found "+ collection + " " + pattern + " " + color + " on line "+x)
t[x,1] = ""
t[x,2] = ""
t[x,3] = ""
t[x,4] = ""
}
x=x+1
} //keep looping till end

writeln("processing record " + @formresultsetcurrentposition("admin") )

vrecord = ""


if @formresultsetcurrentposition("admin") = @formresultsettotal("Admin")
{
writeln("NOW writing results")
vresults = fileopen("C:\temp\results.txt")

x=1

while x <= z
{
if t[x,1] <> "" then
{
filewrite(vresults, t[x,1])
filewrite(vresults, t[x,3])
filewrite(vresults, ",")
filewriteln(vresults, t[x,4])
}
x=x+1
}// loop to write file

fileclose(vresults)
}//end of last record.




Edit: The globalCode section contains:
var z as int
VAR t as array [5000,4] of string

Thanks Erika. Looks like that did it! Still a bug somewhere, but I think I can find it.

I appreciate everyones help and your suggestion of using Mass update rather than manually advancing records using sbasic during an export. Great idea!

Steve