Code

Var vRecCnt as Int
Var vOrigRec as Int
Var vLoop as Int
Var vRecsPerCol as Int
Var vCol as Int
Var vNumInCol as Int
Var vcnt as Int
Var vX as Int
Var vY as Int

//Number of records per column
vRecsPerCol = 40

vOrigRec = @FormResultSetCurrentPosition("Main Form")
vRecCnt = @FormResultSetTotal("Main Form")
vCol = 1
vLoop = 0

NewPage(850, 1100)

//Loop through all the records.
While vLoop < vRecCnt
{
	vLoop = vLoop + 1
	vCnt = vCnt + 1
	FormResultSetCurrentPosition("Main Form", vLoop)

	//Set the X and Y cooridinates
	vX = 100 + ((vCol-1) * 325)
	VY = 50 + (vCnt * 25)

	//Print the information
	PrintString(First , vX, vY, 0, "Arial", 16, 0)
	PrintString(@Text((20 - @Len(Key)) * 2, " ") + Key , vx + 100, vY, 0, "Arial", 16, 0)

	//Check and see if it is time to switch to another column
	If vCnt = vRecsPerCol Then
	{
		If vCol = 1 then
		{
			//Switch to the second column
			vCol = 2
		}
		Else If vCol = 2 then
		{
			//Done with this page. New page and first column again
			vCol = 1
			FinishPage()
			NewPage(850, 1100)
		}
		vCnt = 0
	}
}

If (vCnt > 0) Or (vCol > 1) Then
{
	//A page has been started but not printed... so lets send it to the printer
	FinishPage()
}

//Return to the record I was looking at.
FormResultSetCurrentPosition("Main Form", vOrigRec)