Code

Var vData as String
Var vRecData as String
Var vItem as String
Var vCnt as Int
Var vLoop as Int
Var vRecCnt as Int
Var vRecLoop as Int
Var vQuit as Int
Var vResult as Double
Var vCustNum as String


SetStringArraySeparator(@Newline())
//Get all Data in the File for this Customer

vCustNum = @Str(CustNum)
If @InStr(vCustNum, ",") > 0 Then
{
	vCustNum = @Left(@Str(CustNum), @Len(@Str(CustNum)) - 1)
}
vData = @SearchStringArray(gsFile, vCustNum + "..")

//You can remove these next two lines after everything is working fine
writeln("Searching for a customer number of [" + vCustNum + ".." + "]")
writeln("Length of vData " + @Str(@Len(vData)))

//Remove the data for this customer from the file as it is no longer needed.
gsFile = @DifferenceStringArray(gsFile, vData)

vCnt = @CountStringArray(vData)
vLoop = 1
vRecCnt= @FormResultSetTotal("NewForm0")
vRecLoop = 1
vQuit = 0

//Loop through the data from the text file
While vLoop <= vCnt
{
 vRecData = @AccessStringArray(vData, vLoop)
 RestoreStringArraySeparator()
 //Parse apart
 vItem = @AccessStringArray(vRecData, 2)
 vResult = @AccessStringArray(vRecData, 3)

 //Loop through the subform looking for the record that matches
 While ((vRecLoop <= vRecCnt) And (vQuit = 0))
 {
  If @FormFieldValue("NewForm0", "Metal Type", vRecLoop) = vItem Then
  {
   //Record found. Lets put the result in the subform.
   FormFieldValue("NewForm0", "Result", vRecLoop, vResult)
   If @ToMoney(@FormFieldValue("NewForm0", "Result", vRecLoop)) <> vResult Then
   {
    Writeln("Failed to set the result Element on record " + vRecLoop)
   }
   vQuit = 1
  }
  vRecLoop = vRecLoop + 1
 }
 vRecLoop = 1
 vQuit = 0
 SetStringArraySeparator(@Newline())
 vLoop = vLoop + 1
}