Code

// Returns a date that is vMonths from vStartDate
// Use negative vMonths to get a date before vStartDate
FUNCTION GetDateByMonths(vStartDate as Date, vMonths as Int) as Date
var vRet as Date
var vYear as Int
var vDay as Int
var vMonth as Int
var vOffset as Int
var vDir as Int		// Add (1) or subtract (-1) months

	vRet = vStartDate
	vDir = 1
	vOffset = vMonths

	// Split date into pieces
	vYear = @Int(@Year(vStartDate))
	vDay = @DOM(vStartDate)
	vMonth = @Month(vStartDate)

	// Work with a positive number of months
	If vOffset < 0
	{
		vDir = -1
		vOffset = @Abs(vOffset)
	}

	// Adjust months
	If vDir = 1
	{
		vMonth = vMonth + vOffset

		// Adjust for multiple years
		While vMonth > 12
		{
			vYear = vYear + 1
			vMonth = vMonth - 12
		}
	}
	Else
	{
		vMonth = vMonth - vOffset

		// Adjust for multiple years
		While vMonth < 1
		{
			vYear = vYear - 1
			vMonth = vMonth + 12
		}
	}

	// Assemble new date
	vRet = @Str(vYear) + "/" + @Text(2 - @Len(@Str(vMonth)), "0") + @Str(vMonth) + "/" + @Text(2 - @Len(@Str(vDay)), "0") + @Str(vDay)
	Return vRet

END FUNCTION 

Code

var vBirthdate as Date
var vFirst as Date
var vLast as Date

	vBirthdate = Dog_Birthdate
	vFirst = GetDateByMonths(@ServerDate(), -6)    // Get date six months before today
	vLast = GetDateByMonths(@ServerDate(), -9)     // Get date nine months before today
	If (vBirthdate >= vFirst) And (vBirthdate <= vLast)
	{
		WriteLn("Good Dog!")
	}
	Else
	{
		WriteLn("Bad Dog!")
	}