Hello Tcgeo,
Do you mean lines in between the rows and columns of data, so vertical and horizontal lines? If so, Yes you can. You'd use PrintBox to draw the lines. Below is a piece of sample code. Run this in a Mass Update on a parent record with some subforms, such as the Argentina record, in the Countries sample database.
Var vY as Int
Var vStartingY as Int
Var vHeight as Int
Var vTallest as Int
Var vLoop as Int
Var vCnt as Int
NewPage(850, 1100)
PrintRGBColor(0, 0, 0)
PrintString("Country: " + Country, 100, 100, 0, "BArial", 12, 0)
PrintString("CITIES", 100, 150, 300, "BArial", 12, 0, 2)
vY = 175
PrintBox(14, 100, vY, 300, 2)
vCnt = @FormResultSetTotal("Cities")
vLoop = 1
While vLoop <= vCnt
{
FormResultSetCurrentPosition("Cities", vLoop)
vTallest = 0
vStartingY = vY
//Add 5 for spacing between the line and the data
vY = vY + 5
PrintString(@FormFieldValue("Cities", "City", 0), 110, vY, 130, " Arial", 12, 0)
vHeight = @PrintLastHeight()
If vHeight > vTallest Then
{
vTallest = vHeight
}
PrintString(@Decimals(@FormFieldValue("Cities", "Population", 0), 0), 260, vY, 130, " Arial", 12, 0, 1)
vHeight = @PrintLastHeight()
If vHeight > vTallest Then
{
vTallest = vHeight
}
//Add 5 for spacing between the data and the line
vY = vY + vTallest + 5
//Add 10 to height to account for spacing and 2 to account for horizontal line height
PrintBox(14, 100, vStartingY, 2, vTallest + 12)
PrintBox(14, 250, vStartingY, 2, vTallest + 12)
PrintBox(14, 398, vStartingY, 2, vTallest + 12)
PrintBox(14, 100, vY, 300, 2)
vLoop = vLoop + 1
}
FinishPage()
-Ray