Hello!
I would like to search internally the parent form records with no subform items (with zero items).

And from a external form how to use @XResultSetSearch()   to select that.

thank you for the help

Hello Ray!
i´m using a natural linking.

Hello Amor,

The following little chunk of code would be run from the Main Menu. It gets all the parent records in an application and then loops through checking to see if they have any children. If it finds children, it removes that record from the XResultSet(). If it does not find children it advances to the next record and checks it. Once it checks all records, it opens the appropriate form and displays just the parent records that have no children.

You will need to update Form, Database and Field names to match your application.

Var vParentRS as Int
Var vChildRS as Int
Var vLoop as Int
Var vCnt as Int
Var vRemoved as Int

	vParentRS = @XResultSetSearch(@FN, "GEM TYPES", 0, 2, "!GEM_TYPE=/=")
	If vParentRS >= 0 Then
	{
		vRemoved = 0
		vLoop = 1
		vCnt = @XResultSetTotal(vParentRS)
		While vLoop <= (vCnt - vRemoved)
		{
			XResultSetCurrentPosition(vParentRS, vLoop)
			vChildRS = @XResultSetSubSet(vParentRS, "Gems")
			If @XResultSetTotal(vChildRS) > 0 Then
			{
				//Has Children so remove this record
				XResultSetRemoveRecord(vParentRS)
				vRemoved = vRemoved + 1

			}
			Else
			{
				//No Children so keep this record in the Resultset
				vLoop = vLoop + 1
			}
			XResultSetClose(vChildRs)
		}
		XResultSetOpenForm(vParentRS, "Gem Types")
		XResultSetClose(vParentRS)
	} 

-Ray

I would like to add that you should also include the following code to the end of Ray's code.

If you don't, you will discover some strange behavior with the record counter, record navigation, and may even cause you to create duplicate records by mistake. Adding the following code will get the counter and result set back in sync.

FormResultSetCurrentPosition(@Layout, @FormResultSetTotal(@Layout))
FormResultSetCurrentPosition(@Layout, 1) 

I know that it seems silly to have two FormResultSetCurrentPosition commands in a row, but that's what it takes get things in sync.

Here are the various results that I found:

// Works partially...
// Does NOT work well with navigation buttons that change their visibility based on result set position
ResultSetCurrentPosition(@ResultSetTotal())
ResultSetCurrentPosition(1)


// Does NOT work by itself if there is just one record found
FormResultSetCurrentPosition(@Layout, @FormResultSetTotal(@Layout))


// This works in all cases - shows first record
FormResultSetCurrentPosition(@Layout, @FormResultSetTotal(@Layout))
FormResultSetCurrentPosition(@Layout, 1)


// This works in all cases - shows first record
FormResultSetCurrentPosition(@Layout, 1)
FormResultSetCurrentPosition(@Layout, 1)


// This works in all cases - shows last record
FormResultSetCurrentPosition(@Layout, @FormResultSetTotal(@Layout))
FormResultSetCurrentPosition(@Layout, @FormResultSetTotal(@Layout))

Ray,

Excellent. That is more elegant, resolves the issues I was seeing, and works perfectly in all cases that I tested.

One more thing I would add, is a conditional just before opening the form, to check that there is actually a parent record with zero subrecords, and a message if there are none found. This just reduces the confusion of leaving a user looking at a blank form in update mode.

Var vParentRS as Int
Var vChildRS as Int
Var vLoop as Int
Var vCnt as Int
Var vRemoved as Int

	vParentRS = @XResultSetSearch(@FN, "GEM TYPES", 0, 2, "!GEM_TYPE=/=")
	If vParentRS >= 0 Then
	{
		vRemoved = 0
		vLoop = 1
		vCnt = @XResultSetTotal(vParentRS)
		While vLoop <= (vCnt - vRemoved)
		{
			XResultSetCurrentPosition(vParentRS, vLoop)
			vChildRS = @XResultSetSubSet(vParentRS, "Gems")
			If @XResultSetTotal(vChildRS) > 0 Then
			{
				//Has Children so remove this record
				XResultSetRemoveRecord(vParentRS)
				vRemoved = vRemoved + 1

			}
			Else
			{
				//No Children so keep this record in the Resultset
				vLoop = vLoop + 1
			}
			XResultSetClose(vChildRs)
		}
		XResultSetCurrentPosition(vParentRS, 1)

		If vLoop > 1
			XResultSetOpenForm(vParentRS, "Gem Types")
		Else
			@MsgBox("No records found that have zero subrecords.", "", "")

		XResultSetClose(vParentRS)
	}