Code

var vRS as Int
var vState as String
var vOldState as String
var vLoop as Int
var vCnt as Int
var vStateList as String
var vTotal as Double
var vAmount as Double
var vRecs as Int
var vMinDate as Date
var vMaxDate as Date
var vDate as Date

SUBROUTINE CalcAndEmit()
// this calc will determine the average # of days
// btwn orders, and the average qty per order

var vAvgInterval as Int
var vPredictedDate as Date
var vAvgQty as Int

	vAvgInterval = 0
	vAvgQty = 0
	vPredictedDate = vDate
	If vRecs > 0
	{
		vAvgInterval = @DefinedRound((@ToNumber(vMaxDate) - @ToNumber(vMinDate)) / vRecs, 0, 1)
		vPredictedDate = vMaxDate + vAvgInterval
		vAvgQty = @DefinedRound(vTotal / vRecs, 0, 1)
		If vAvgQty < 1
		{
			vAvgQty = 1
		}
//		If (vPredictedDate > (vDate - 7)) and (vPredictedDate < (vDate + 7))
		If (1 = 1)	// Forcing output since none of the sample dates are current
		{
			WriteLn("Reorder Date for " + vAvgQty + " of ItemNum #" + vOldState + @NewLine() + " should be " + vPredictedDate + @NewLine() + @NewLine())
			// vNeedSoonAddTo = ""
			// vNeedSoonAddTo = "Reorder Date for " + vAvgQty + " " + vItemUoM + " of ItemNum #" + vItemNum + " / " + vItemDesc + @NewLine() + " should be " + vPredictedDate + @NewLine() + @NewLine()
			// vNeedSoonFYI = vNeedSoonFYI + vNeedSoonAddTo + @NewLine()
		}
	}

END SUBROUTINE

	vDate = @Date

	// Get list of unique States as a StringArray
	// We don't need them to be in order, so we're
	// not gonna waste time on sorting
	vStateList = ""
	vRS = @XResultSetSearch(@FN, "Customers", 0, 2, "")
	If vRS > -1
	{
		vCnt = @XResultSetTotal(vRS)
		For vLoop = 1 To vCnt
			XResultSetCurrentPosition(vRS, vLoop)
			vState = @XResultSetValue(vRS, "State")
			vStateList = vStateList + vState + ";"
		Next
		XResultSetClose(vRS)
	}
	vStateList = @Repllas(vStateList, ";", "")
	vStateList = @UniqueStringArray(vStateList)

	// Get calc info for all the States at once instead of doing
	// one @XResultSetSearch for each State by using the list assembled
	// above as search criteria.
	vRS = @XResultSetSearch(@FN, "Customers", 0, 2, "!State=" + vStateList, "!Company=/=")
 	If vRS > -1
	{
		// Now the sort order matters
		XResultSetSort(vRS, "State:-1;Date_Entered:-1")
		vCnt = @XResultSetTotal(vRS)
		vOldState = "This will never appear as a State"
		vTotal = 0
		vRecs = 0

		// Calc each State
		For vLoop = 1 To vCnt
			XResultSetCurrentPosition(vRS, vLoop)
			vState = @XResultSetValue(vRS, "State")
			If vOldState <> vState
			{
				If vOldState <> "This will never appear as a State"
				{
					CalcAndEmit()	// Emit result
				}
				// Reset for next State
				vOldState = vState
				vMinDate = @ToDate(@XResultSetValue(vRS, "Date_Entered"))
				vMaxDate = vMinDate
				vTotal = 0
				vRecs = 0
			}
			vMaxDate = @XResultSetValue(vRS, "Date_Entered")
			vAmount = @XResultSetValue(vRS, "Numerical")
			vTotal = vTotal + vAmount
			vRecs = vRecs + 1
		Next
		XResultSetClose(vRS)
		CalcAndEmit()	// Emit last State
	}