Am experimenting with generating, for some of my clients, invoices that are automatically saved as files and then emailed automatically instead of hard copy printed and snail mailed.    Here's my rough code to do so (not polished, not caveats inserted yet to look for same name file, etc):



FormViewType("SOLines", 1)
                                                     
vPrt = @PrintAFormToHTML(vSONum + ".html")
                                                           
If vPrt = 0
{
  Writeln("error: Failed to create " + vSONum + ".html")
}

   else if vPrt = 1
           {
               vInvoice = vSONum + ".html"
               vEmail = @sendmail("smtp2go.com","MyCompanyInvoice","MyServer@gmail.com","Customer@gmail.
com","","","Here is MyCompany invoice " + vSONum,"","",vInvoice)
            }

It works great!  But (isn't there always?), even though the programming turns the SOLines subform into tableview just prior to printing, when printed to the html file, it prints the 'form view' of the SOLines subform (which is unacceptable).

Is the inability to print a normally formview subform in tableview a limitation of @PrintAFormToHTML?   

Hi Carl,

Yes, you're right, of course - a pdf attached to an email would be preferable.  Actually, we do it that way for 8 or 10 clients now.  But our current procedure is cumbersome: we 'print the invoice' to a pdf print driver that pops up a user interaction screen that requires us to manually give the pdf a filename.  So it's certainly not an ideal solution. 
   I'm wanting to come up with a completely automated programmed solution, in anticipation of converting maybe half of my 700 invoices/month to email.

I'm looking to have the Sesame programming automatically 1)  print the invoice to a file (programmatically assigning a file name)  - and then
2) emailing the digital invoice to the client's email address.

I'm certainly open to advice on how to do that.

ps - out of curiosity, though, what is the drawback to attaching the html file to an email?  Anti-Virus filters on customers' email settings?

This isn't a perfect solution, but it works for me. I use the following subroutine to use the command line to call Thunderbird (open source email client) to file attach an HTML report. I use this on my 'Estimates' form, so that my sales reps don't have to manually 'find' the file that they want to attach.

// The Thunderbird() subroutine take four arguments (all as STR) in the order of SendAddress, Subject, Body and the Attachments.
// The subroutine allows for multiple address and attachments, so long as the inputs are string arrays.
// Also, this subroutine assumes that the default Thunderbird install directory is the same on all computers.
SUBROUTINE Thunderbird(vToAddress as String, vSubject as String, vBody as String, vAttachment as String)
var vCommand as String
var vLoop as Int

If vToAddress <> "" // Not a blank vToAddress value.
{
	If @CountStringArray(vToAddress) = 1
	{
		vCommand = "to=" + vToAddress
	}
	Else // More than one address to be sent.
	{
		vCommand = "to='"
		For vLoop = 1 to @CountStringArray(vToAddress)
			vCommand = vCommand + @AccessStringArray(vToAddress, vLoop) + ","
		Next
		// Now remove the trailing ","
		vCommand = @TrimStringRight(vCommand, ",")
		// Now add the last "'".
		vCommand = vCommand + "'"
	}
}

If vSubject <> "" // Not a blank vSubject value.
{
	vCommand = vCommand + "," + "subject=" + vSubject
}

If vBody <> ""
{
	vCommand = vCommand + "," + "body=" + vBody
}

If vAttachment <> ""
{
	If @CountStringArray(vAttachment) = 1
	{
		vCommand = vCommand + "," + "attachment=file:///" + vAttachment
	}
	Else
	{
		vCommand = vCommand + "," + "attachment='"
		For vLoop = 1 to @CountStringArray(vAttachment)
			vCommand = vCommand + "file:///" + @AccessStringArray(vAttachment, vLoop) + ","
		Next
		// Now remove the trailing ","
		vCommand = @TrimStringRight(vCommand, ",")
		// Now add the last "'"
		vCommand = vCommand + "'"
	}
}
// Add final quote marks to vCommand string.
vCommand = @Chr(34) + vCommand + @Chr(34)
CreateAProcess("C:\Program Files\Mozilla Thunderbird\thunderbird.exe -compose" + " " + vCommand)
END SUBROUTINE
 

Here's an example of how the subroutine is called on my 'Estimates' form, from a Print/Preview command button:

var vPDFLocation as String
var vPDFChoices as String
var vRS as int
var vReportFileName as string
var vChoice as String
var vPDFChoice as String
var vChoices as String
var vAttachment as String

vChoices = "Preview/Print;Email"

//vPDFLocation = "C:\Sesame2\Data\PDFs" // This specifies that the local directory be used.
vPDFLocation = "P:\Sesame2\Data\PDFs"
vPDFChoices = @LocalListDirectory(vPDFLocation)

PopupSelectPosition(4, @XPos(ThisElement) + 80, @YPos(ThisElement))

If NOT @IsNew // This record has been saved!
{
	vChoice = @PopupChoiceList(vChoices, "Select A Print Option")

	If vChoice = "Preview/Print"
	{
		vRS = @XResultSetSearch(@FN, "CLIENTS!ESTIMATES", 0, 2, "!ESTIMATENUMBER=" + ESTIMATENUMBER)
		If vRS > -1
		{
			If @XResultSetTotal(vRS) = 1
			{
				vReportFileName = @XResultSetPrintReport("Print Estimate Form", vRS, 1)
			}
			Else
			{
				@MsgBox("Two records were found with the Estimate Number: " + ESTIMATENUMBER, "The estimate cannot be printed.","Please contact CJ.")
			}
			XResultSetClose(vRS)
		}
		Else
		{
			@MsgBox("A valid result set could not be created.", "This is a serious error.", "Contact CJ.")
		}
	}

	If vChoice = "Email"
	{
		If @IsBlank(EMAIL) <> 1
		{
			vPDFChoice = @PopupChoiceList(vPDFChoices, "Include a PDF?")
			If vPDFChoice <> ""
			{
				vAttachment = vPDFLocation + "\" + vPDFChoice
			}

			vRS = @XResultSetSearch(@FN, "CLIENTS!ESTIMATES", 0, 2, "!ESTIMATENUMBER=" + ESTIMATENUMBER)
			If vRS > -1
			{
				If @XResultSetTotal(vRS) = 1
				{
					vReportFileName = @XResultSetPrintReport("Print Estimate Form", vRS, 1)
					If @CountStringArray(vAttachment) = 1
					{
						vAttachment = @AppendStringArray(vReportFileName, vAttachment)
					}
					Else
					{
						vAttachment = vReportFileName
					}
				}
				Else
				{
					@MsgBox("Two records were found with the Estimate Number: " + ESTIMATENUMBER, "The estimate cannot be printed.", "Please contact CJ.")
				}
				XResultSetClose(vRS)
				ThunderBird(EMAIL, "Ace Banner Estimate #" + ESTIMATENUMBER, "", vAttachment)
			}
			Else
			{
				@MsgBox("A valid result set could not be created.", "This is a serious error.", "Contact CJ.")
			}
		}
		Else
		{
			@MsgBox("This estimate cannot be emailed because the contact","does not have an email address listed.","")
		}
	}
}
Else
{
	@MsgBox("Please SAVE this record before you print it.", "Hit the SAVE button and then try again.", "")
}
 

When the command button programming is called, the user gets a choice of simply viewing the estimate (as its an HTML, whatever internet browser is available is used), or emailing it. In either case, the HTML report is shown. If emailing was selected then the user is asked if they would like to add any additional files to the email. My company does graphic work, so we usually add a PDF for artwork submission guidelines, etc. After that, the Thunderbird email composing window pops up with the major fields filled out -- the client's email, the subject line, and the estimate report is attached. The user can then fill out the body with whatever they need, and hit send.

The major drawbacks are that the file is not a PDF, and it gets the Sesame default name. Not a perfect solution, but maybe a starting point. I would much prefer to send a PDF file, but I never managed to figure out how to print one automatically to a file.

Hope this helps.