Yes Flip, that can be done and I use that very frequently in my program. The process is:

1. You create subform record just as you create normal record.

2. Open Parent Record (of course the Resultset)

3. You reparent the child record (Subform record) to Parent (Mainform record)

I have pasted important part of one of my codes to do that just to give you an idea that how it could be done.

If @clientLocalValue ("Process") = "Success" and vDescription <> ""then  //only when processed properly - to avoid putting value in Document subform
						{



							vChildRSID = @XResultSetSearch(@FN, "Client!Documents", SEARCH_MODE_AND, SEARCH_SYNTAX_QA, "!Chart==")

							If vChildRSID > -1 then
								{
									xResultSetCreateNewRecord (vChildRSID)
									xResultSetValue (vChildRSID, "RecNumber", vRecNumber)
									xResultSetValue (vChildRSID, "DateAdded", vDateAdded)
									xResultSetValue (vChildRSID, "Chart", vChart)
									xResultSetValue (vChildRSID, "Description", vDescription)
									xResultSetValue (vChildRSID, "View", vView)
									xResultSetValue (vChildRSID, "FileName", vFileName)
									xResultSetValue (vChildRSID, "Key", vKey)
									//since it is processed from Index Database - to be reparent later either in Menu through button or Physical Form On Exit Event of DX2 when Record is New
									//xResultSetValue (vChildRSID, "Marker", 1)


									xResultSetClose (vChildRSID)

								}

							vParentRSID = @XResultSetSearch(@FN, "Client", SEARCH_MODE_AND, SEARCH_SYNTAX_QA, "!Chart=" + vChart)


								If @XResultSetLocked (vParentRSID) = 1 Then
									{
										@MSGBox ("Parent ResultSet is Locked", "The Document will not go to DocumentSubform", "Process it from Other Database")

									}




							If vParentRSID > -1 then
								{
									vRecordsFound = @XResultSetTotal (vParentRSID)

									If vRecordsFound = 1 then
										{
											//ClientLocalValue ("DocToBeReParented", "Yes")   // ReParenting will be either done in Menu or DX2 on  Exit Event of Physical when Record is New


											vChildRSID = @XResultSetSearch(@FN, "Client!Documents", SEARCH_MODE_AND, SEARCH_SYNTAX_QA, "!Chart=" + vChart, "!Key=" + vKey)

											If vChildRSID > -1 then
												{
													If @XResultSetTotal (vChildRSID) = 1 then
														{

											                               // xResultSetSort (vChildRSID, "DateAdded:1")  //Since this is just one record, sorting will not work
															xResultSetReparent (vParentRSID, "DocumentSubForm", vChildRSID)

															If @Error = 1 then
																{
																	WriteLN ("Reparent Failed")
																}
														}


													xResultSetClose (vChildRSID)
												}

										}

										Else if vRecordsFound = 0 then
										{
											WriteLN ("Chart " + vChart + " Does not exist in Client Database!!! Please Correct it" )
											vFailureIndicator = 1
										}
										Else if vRecordsFound > 1 then
										{

											WriteLN ("Chart " + vChart + " has Multiple Entries in Client Database!!! Please Correct it" )
											vFailureIndicator = 1
										}

									XResultSetClose (vParentRSID)


								}
							xResultSetClose (vChildRSID)       // for additional precaution - in case if it is not closed
							xResultSetClose (vParentRSID)		// for additional precaution - in case if it is not closed

						}
 

Is EquipList is the Subrecord field name? I believe the Subrecord Field name goes there.

xResultSetReparent(vParentRSID, "Equiplist", vChildRSID)

yes,

#1
Display form "Equipment List"

#2
"Automatic (natural links)"

#3
""
#4
"Equiplist"

#5 "Tables"

I even tried it leaving the vChildRSID open and did the @msgbox("", vChildRSID,"") double checked spelling also.
funny thing is my popup box uses a key field "co_name" to populate so it shows up, just not the subform of the customer database. its just an orphan

Computers works well with numbers. I create one unique number for chart or record that goes in both parent and child records. It is text field (String)

If @Mode ( ) = 0 and Name <> "" and Record = "" then  //Name is the required field - This code  will create record in Attachment Database, so one can attach a file while addting the record
							//Record Number required before before subrecord is created
	{


		If @IsNew = 1 and Record = "" then
			{

				vRecordNumber = @TN (@GlobalValue ("RecordNumber")) + 1

							Globalvalue ("RecordNumber", @str (vRecordNumber))

							vNumberExtension = "00000" + @GlobalValue ("RecordNumber")
							vNumberExtension = @Right (vNumberExtension, 5)
							Record = vNumberExtension

			}


	}

 

This comes very handy if for any reasons parent and children gets separated... it has one to many relations and you can easily reparent them.

The other unique field only goes in the SubDatabase, I called that Key field. It is just used to choose the last child record created.

vNextNumber = @ToNumber (@GlobalValue ("RecordLocator")) + 1
								//WriteLn ("This is Next Number " + vNextNumber)
								GlobalValue ("RecordLocator", vNextNumber)
								vNextNumber = @text (7 - @Len (vNextNumber), "0") + vNextNumber
								vKey = vNextNumber
 

Problem here could be, one ends up choosing multiple or none records either in child resultset or parent resultset. Using Numerical value (eventhough technically it is string) make it easier to deal with them to select one record each.

Looking at the creation of the child record, all of the values are coming directly from elements and not from variables. Where are you initiating this from?

XResultSetCreateNewRecord(vChildRSID)
								XResultSetValue(vChildRSID, "Equipment_Type", Machine_Type)
								XResultSetValue(vChildRSID, "other_info", eqinfo2)
								XResultSetValue(vChildRSID, "Model_No", DModel)
								XResultSetValue(vChildRSID, "Serial_No", DSerial)
								XResultSetValue(vChildRSID, "Last_Updated_On", CallDate)
								XResultSetValue(vChildRSID, "Co_Name", CompanyName)
 

Machine_Type
DSerial
DModel
CallDate
CompanyName

All of the above seems to be elements of the form where you are initiating this code.. Is that so?

XResultSetValue ( ) command post the value.

Since you are making the subform record from the same database form that the subform is attached to, you will have to use following method.

					If @clientLocalValue ("Process") = "Success" and vDescription <> ""then  //only when processed properly - to avoid putting value in Document subform
						{


						If vDescription <> "" and @FormFieldValue ("Documents", "Description", 1) = "" then
							{


								//nn = @FormNewRecord ("Scripts2")
								//WriteLN ("vLoop = " + @str (vLoop))
								//WriteLN ("nn = " + @str (nn))
								FormresultsetCurrentPosition ("Documents", 1)

								FormFieldValue ("Documents", "RecNumber", 1, vRecNumber)
								FormFieldValue ("Documents", "DateAdded", 1, vDateAdded)
								FormFieldValue ("Documents", "Chart", 1, Chart)
								FormFieldValue ("Documents", "Description", 1, vDescription)
								FormFieldValue ("Documents", "View", 1, vView)
								FormFieldValue ("Documents", "FileName", 1, vFileName)
								FormFieldValue ("Documents", "Key", 1, vKey)
								FormFieldValue ("Documents", "Print", 1, @Chr (252) )






								FormCommit ("Documents")

							}
						Else if vDescription <> "" and @FormFieldValue ("Documents", "Description", 1) <> "" then
							{




								nn = @FormNewRecord ("Documents")
								//WriteLn ("The value on nn = " + @Str (nn) )




								//WriteLN ("vLoop = " + @str (vLoop))
								//WriteLN ("nn = " + @str (nn))

								FormFieldValue ("Documents", "RecNumber", nn, vRecNumber)
								FormFieldValue ("Documents", "DateAdded", nn, vDateAdded)
								FormFieldValue ("Documents", "Chart", nn, Chart)
								FormFieldValue ("Documents", "Description", nn, vDescription)
								FormFieldValue ("Documents", "View", nn, vView)
								FormFieldValue ("Documents", "FileName", nn, vFileName)
								FormFieldValue ("Documents", "Key", nn, vKey)
								FormFieldValue ("Documents", "Print", nn, @Chr (252) )

								Formcommit ("Documents")




							}

 

First it checks whether the first record is blanked or not. Logic is the first record in the subform always exists. If it is blank you just fill it up. Subsequent record you make and fill it up. 

I have gone through this frustrations in the past. But now it is clear. If you make subrecord from other database, you use XResultset command. If you make it from the same database form, you use @Formfieldvalue ( ). I am quite sure this should work for you.