Code

Stat BigOnes as array[9] of String
Stat SmallOnes as array[19] of String

Subroutine ParseChunk(Var vChunk as String, Var vWords as String) //##########
Var vLeftDigit as Int
Var vRightDigit as Int
Var vDigits as Int

	vLeftDigit = 0
	vRightDigit = 0

	vDigits = @Left(vChunk, 1)
	If vDigits > 0 Then
	{
		If vWords <> "" Then
		{
			vWords = vWords + " "
		}
		vWords = vWords + SmallOnes[vDigits] + " Hundred"
	}
	vDigits = @Mid(vChunk, 2, 2)
	If vDigits > 19 Then
	{
		vLeftDigit = @Mid(vChunk, 2, 1)
		vRightDigit = @Mid(vChunk, 3, 1)
		If vWords <> "" Then
		{
			vWords = vWords + " "
		}
		vWords = vWords + BigOnes[vLeftDigit]
	}
	If vRightDigit > 0 Then
	{
		If vWords <> "" Then
		{
			vWords = vWords + " "
		}
		vWords = vWords + SmallOnes[vRightDigit]
	}
	Else
	{
		If (vDigits <= 19) and (vDigits > 0) Then
		{
			If vWords <> "" Then
			{
				vWords = vWords + " "
			}
			vWords = vWords + SmallOnes[vDigits]
		}
	}
End Subroutine //##################

Function MoneyToText(vAmount as Money) as String
var vWords as String
var vDollars as String
var vCents as String
var vChunk as String

	vWords = ""

	If vAmount <> 0 Then
	{
		If @Int(vAmount) > 999999 Then
		{
			@Msgbox("","Dollar amount too large.","")
		}
		Else
		{
			// Separate the dollars from the cents
			// Format incoming number to ensure 6 digits
			// to the left of the decimal & 2 to the right
			vDollars = @Int(vAmount)
			vDollars = @Right("000000" + vDollars, 6)
			vCents = @Frac(vAmount)
			vCents = @Right("00" + vCents, 2)

			// Separate the dollars into chunks
			If @Int(vDollars) = 0 Then
			{
				vWords = "Zero"
			}
			Else
			{
				// First do the thousands
				vChunk = @Left(vDollars, 3)
				If @Int(vChunk) > 0 Then
				{
					ParseChunk(vChunk, vWords)
					vWords = vWords + " Thousand"
				}

				// Do the rest of the dollars
				vChunk = @Right(vDollars, 3)
				If @Int(vChunk) > 0 Then
				{
					ParseChunk(vChunk, vWords)
				}
			}

			vWords = vWords + " and " + vCents + "/100"
		}
	}
	Return(vWords)
End Function

BigOnes[1] = "Ten"
BigOnes[2] = "Twenty"
BigOnes[3] = "Thirty"
BigOnes[4] = "Forty"
BigOnes[5] = "Fifty"
BigOnes[6] = "Sixty"
BigOnes[7] = "Seventy"
BigOnes[8] = "Eighty"
BigOnes[9] = "Ninety"
SmallOnes[1] = "One"
SmallOnes[2] = "Two"
SmallOnes[3] = "Three"
SmallOnes[4] = "Four"
SmallOnes[5] = "Five"
SmallOnes[6] = "Six"
SmallOnes[7] = "Seven"
SmallOnes[8] = "Eight"
SmallOnes[9] = "Nine"
SmallOnes[10] = "Ten"
SmallOnes[11] = "Eleven"
SmallOnes[12] = "Twelve"
SmallOnes[13] = "Thirteen"
SmallOnes[14] = "Fourteen"
SmallOnes[15] = "Fifteen"
SmallOnes[16] = "Sixteen"
SmallOnes[17] = "Seventeen"
SmallOnes[18] = "Eighteen"
SmallOnes[19] = "Nineteen"